Install and use providers, and understand state

Declare providers in required_providers with a source and a version constraint. terraform init downloads them and writes the exact versions into .terraform.lock.hcl.

terraform {
  required_version = ">= 1.12"
  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "~> 4.20"
    }
    random = {
      source  = "hashicorp/random"
      version = ">= 3.6, < 4.0"
    }
  }
}

$terraform init
$terraform init -upgrade
$terraform providers
$terraform version

A provider turns resources in your code into API calls (create, read, update, delete). Each provider brings its own resource types and data sources.

One configuration can use many providers — and the same provider several times with different settings, using an alias.

provider "azurerm" {
  features {}
  subscription_id = var.sub_prod
}
 
provider "azurerm" {
  alias           = "dr"
  features {}
  subscription_id = var.sub_dr
}
 
resource "azurerm_resource_group" "dr" {
  provider = azurerm.dr
  name     = "rg-web-dr"
  location = "northeurope"
}

Never write passwords or keys in .tf files. Use the platform's normal login or environment variables.

$az login
$export ARM_SUBSCRIPTION_ID=00000000-0000-0000-0000-000000000000
$export ARM_USE_OIDC=true

Terraform saves what it created in a state file (terraform.tfstate): the mapping between your code and the real resource IDs, plus their attributes.

$terraform state list
$terraform show